Jump to content
  • 0
Sign in to follow this  
X Seifador X

[Resolvido] Empacotador

Question

Boa Tarde, bom estou com um erro no script Empacotador assim quando eu dou os item ele não dar a box de volta ele simplesmente fica com os item e não da a box. teria como alguém me ajuda? obrigado qual quer ajuda 

Spoiler

// Author: _Okuz_
// Version: 1.0.1 17:32 05/09/2017

prontera,163,195,5    script    Empacotador#Packer    750,{

    mes "[Empacotador]";
    mes "Bem vindo nobre viajante!";
    mes "Você gostaria de escutar uma pequena história?";
    next;
    if (select("Sim:Não")==1) {
        mes "[Empacotador]";
        mes "Durante a minha jornada por todos os reinos de Midgard, me especializei como Empacotador de diversos tipos de mercadorias.";
        next;
        mes "[Empacotador]";
        mes "Empacotadores são mercadores especializados na arte de criar caixas especiais para comportar mais items ocupando menos espaço e aliviando o peso.";
        next;
        mes "[Empacotador]";
        mes "Os itens que mais gosto de empacotar são poções. Você sabia que quando bem acomodadas nas caixas o risco de vazamento e danificação durante o transporte é praticamente nulo? Legal não!? :P";
        next;
        mes "[Empacotador]";
        mes "É importante lembrar que as vezes tenho que me ausentar devido as altas demandas de trabalho, por isso se você precisar dos meus serviços recomendo que você tente me visitar sempre que surgir um novo dia para saber se estou por aqui!";
        next;
    }
    mes "[Empacotador]";
    mes "Então diga-me, o que posso fazer por você?";
    next;
    if(select("Lista de pacotes.:Empacotar item.")==1) {
        for (.@i=0; .@i<.item_count; .@i+=3) {
            mes "["+.item_db$[.@i+2]+"x - "+getitemname(atoi(.item_db$[.@i+1]))+"]";
            deletearray(.@id_amount$[0],getarraysize(.@id_amount$));
            explode(.@id_amount$,.item_db$[.@i],":");
            .@tmp_count=getarraysize(.@id_amount$);
            for (.@j=0; .@j<.@tmp_count; .@j+=2)
                mes "- "+.@id_amount$[.@j+1]+"x - "+getitemname(atoi(.@id_amount$[.@j]))+".";
            next;
        }
    }
    mes "[Empacotador]";
    mes "Posso criar os seguintes pacotes:";
    next;
    .@menu$=getitemname(atoi(.item_db$[1]));
    for (.@i=4; .@i<.item_count; .@i+=3)
        .@menu$+=":"+getitemname(atoi(.item_db$[.@i]));
    .@option=(select(.@menu$)-1)*3;
    deletearray(.@id_amount$[0],getarraysize(.@id_amount$));
    explode(.@id_amount$,.item_db$[.@option],":");
    .@tmp_count=getarraysize(.@id_amount$);
    .@materials$=.item_db$[.@option];
    for (.@i=0; .@i<.@tmp_count; .@i+=2) {
        .@actual=getd("packer_"+.item_db$[.@option+1]+"_"+.@id_amount$[.@i])+countitem(atoi(.@id_amount$[.@i]));
        setd "packer_"+.item_db$[.@option+1]+"_"+.@id_amount$[.@i],.@actual;
        if (countitem(atoi(.@id_amount$[.@i])))
            delitem atoi(.@id_amount$[.@i]),countitem(atoi(.@id_amount$[.@i]));
        if (.@actual>=atoi(.@id_amount$[.@i+1]))
            .@delivered_complete++;
        .@materials$=replacestr(.@materials$, .@id_amount$[.@i]+":"+.@id_amount$[.@i+1], .@id_amount$[.@i]+":"+(atoi(.@id_amount$[.@i+1])-.@actual));
    }
    if (.@delivered_complete==.@tmp_count/2) {
        getitembound atoi(.item_db$[.@option+1]),atoi(.item_db$[.@option+2]),Bound_Char;
        explode(.@id_amount$,.item_db$[.@option],":");
        .@tmp_count=getarraysize(.@id_amount$);
        for (.@i=0; .@i<.@tmp_count; .@i+=2)
            setd "packer_"+.item_db$[.@option+1]+"_"+.@id_amount$[.@i],0;
        mes "Aqui está o(a) "+getitemname(atoi(.item_db$[.@option+1]))+", volte sempre!";
    }
    else {
        mes "[Empacotador]";
        mes "Restam os seguintes ingredientes para finalizar o(a) "+getitemname(atoi(.item_db$[.@option+1]))+".";
        mes " ";
        explode(.@id_amount$,.@materials$,":");
        .@tmp_count=getarraysize(.@id_amount$);
        for (.@i=0; .@i<.@tmp_count; .@i+=2)
            mes "- "+.@id_amount$[.@i+1]+"x - "+getitemname(atoi(.@id_amount$[.@i]))+".";
    }
    close;

OnInit:
    // INICIO DAS CONFIGURAÇÕES
    setarray .item_db$[0],"504:1000",12531,10,                 // Caixa de Poções Brancas [100]
                 "522:1000",12530,10,                 // Caixa de Mastelas [100]
                 "526:1000",12532,10,                 // Caixa de Geléias Reais [100]
                 "547:2000",12529,10,                 // Caixa de Poções Brancas Compactas [200]
                 // "545:1000:546:1000:547:1000:505:1000",12831,10, // Caixa de Poções [100] - Implemente este item antes de descomentar esta linha.
                 "608:300",12534,10;                 // Caixa de Sementes de Yggdrasil [30]
    // FIM DAS CONFIGURAÇÕES

    .item_count=getarraysize(.item_db$);

OnClock0000:
    if (!rand(2))
        disablenpc strnpcinfo(3);
    else
        enablenpc strnpcinfo(3);
}
 

 

Share this post


Link to post
Share on other sites

6 answers to this question

Recommended Posts

  • 0

Algum erro na console do map-server?

Qual o hash/nr da revisão?

Se possível tire print-screens do processo inteiro para que eu possa analisar, crie as poções e vá entregando até chegar ao limite. Registre o ultimo chat para que possamos ver o que está havendo.

Talvez seja um problema com esta linha:

getitembound atoi(.item_db$[.@option+1]),atoi(.item_db$[.@option+2]),Bound_Char;

Troque-a para:

getitembound atoi(.item_db$[.@option+1]),atoi(.item_db$[.@option+2]),4;

Tenho quase certeza que é isso, tendo em vista que as constantes deste comando não existem ainda no Cronus/Hercules.

Att,
_Okuz_.

Edited by Okuz
  • Love 1

Share this post


Link to post
Share on other sites
  • 0

Olá X Seifador X,

Acabo de testar o script e não obtive erro algum. O progresso da quest foi registrado conforme eu entregava as poções até alcançar o limite para criar a box.

https://imgur.com/a/AdzHr

Como você pode ver, gerei 99 + 1 + 300 + 300 + 300 (1000) poções brancas, totalizando 5 entregas, e na 5ª entrega recebi 10 box de poções brancas.

Att,
_Okuz_.

Edited by Okuz

Share this post


Link to post
Share on other sites
  • 0
9 minutos atrás, Okuz disse:

Olá X Seifador X,

Acabo de testar o script e não obtive erro algum. O progresso da quest foi registrado conforme eu entregava as poções até alcançar o limite para criar a box.

https://imgur.com/a/AdzHr

Como você pode ver, gerei 99 + 1 + 300 + 300 + 300 (1000) poções brancas, totalizando 5 entregas, e na 5ª entrega recebi 10 box de poções brancas.

Att,
_Okuz_.

estranho isso porque no meu eu só dou os item e ele não me da os item na box.

Share this post


Link to post
Share on other sites
  • 0
12 minutos atrás, Okuz disse:

Algum erro na console do map-server?

Qual o hash/nr da revisão?

Se possível tire print-screens do processo inteiro para que eu possa analisar, crie as poções e vá entregando até chegar ao limite. Registre o ultimo chat para que possamos ver o que está havendo.

Talvez seja um problema com esta linha:


getitembound atoi(.item_db$[.@option+1]),atoi(.item_db$[.@option+2]),Bound_Char;

Troque-a para:


getitembound atoi(.item_db$[.@option+1]),atoi(.item_db$[.@option+2]),4;

Tenho quase certeza que é isso, tendo em vista que as constantes deste comando não existem ainda no Cronus/Hercules.

Att,
_Okuz_.

era isso mesmo manin vlw ae.

Share this post


Link to post
Share on other sites
  • 0

Eu que agradeço! Obrigado por informar o erro.

Vou efetuar a correção do arquivo lá nos downloads também.

Att,
_Okuz_.

Share this post


Link to post
Share on other sites
Guest
This topic is now closed to further replies.
Sign in to follow this  

Seja bem vindo ao Cronus-Emulator.
É sempre um prazer te-lo conosco.
Você pode visualizar nossas áreas de suporte para encontrar suas soluções sem a necessidade de se registrar!
Registrando em nossa comunidade, você poderá conhecer mais sobre nosso projeto, criar tópicos, responder tópicos existentes, baixar milhares de recursos em nosso sistema de downloads, participar de nossa comunidade, customizar seu perfil e muito mais... Se você já possui uma conta, faça seu login - ou crie uma conta. Também temos integração com Google+ e Facebook.

×
×
  • Create New...